@echo off

REM This batch file can be used to start Slicer through Remote Desktop.
REM It stops current remote desktop session and starts Slicer.
REM User has to connect through remote desktop, start this batch file,
REM then connect through remote desktop again.

REM Make sure the batch file is started in admin mode, if not then switches to that
REM (required for tscon command).
:: BatchGotAdmin
::-------------------------------------
REM  --> Check for permissions
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"

REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
    echo Requesting administrative privileges...
    goto UACPrompt
) else ( goto gotAdmin )

:UACPrompt
    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
    set params = %*:"="
    echo UAC.ShellExecute "cmd.exe", "/c %~s0 %params%", "", "runas", 1 >> "%temp%\getadmin.vbs"

    "%temp%\getadmin.vbs"
    del "%temp%\getadmin.vbs"
    exit /B

:gotAdmin
    pushd "%CD%"
    CD /D "%~dp0"
::--------------------------------------

REM Kill remote desktop session before starting Slicer
tscon 1 /dest:console

REM Start Slicer (user has to reconnect to use Slicer)
Slicer.exe